chore: project scaffolding and CI

Gradle 9.4 multi-module setup with Kotlin DSL and version catalog. GitHub Actions builds on push and PR with JDK 25 (Temurin).
2026-04-28 16:29:46 +02:00
commit e201a227ea
11 changed files with 516 additions and 0 deletions
@@ -0,0 +1,28 @@
+plugins {
+    alias(libs.plugins.kotlin.jvm) apply false
+}
+
+group = findProperty("libGroup") as String? ?: "com.mythlane"
+version = findProperty("libVersion") as String? ?: "0.1.0-SNAPSHOT"
+
+subprojects {
+    group = rootProject.group
+    version = rootProject.version
+
+    plugins.withId("org.jetbrains.kotlin.jvm") {
+        extensions.configure<org.jetbrains.kotlin.gradle.dsl.KotlinJvmProjectExtension> {
+            jvmToolchain(25)
+            compilerOptions {
+                jvmTarget.set(org.jetbrains.kotlin.gradle.dsl.JvmTarget.JVM_24)
+                freeCompilerArgs.addAll("-Xjsr305=strict", "-Xjvm-default=all")
+            }
+        }
+        tasks.withType<JavaCompile>().configureEach {
+            options.release.set(24)
+        }
+        tasks.withType<Test>().configureEach {
+            useJUnitPlatform()
+            jvmArgs("-Dnet.bytebuddy.experimental=true")
+        }
+    }
+}